; --------------------------------------------------------------------------------
; @Title: TRACE32 PowerView Default Startup Script (t32.cmm)
; @Description:
;   Default startup PRACTICE script for TRACE32
;   Please do   n o t   modify this TRACE32 system file!!!
;   Please use instead the files ~~/system-settings.cmm, UAD/user-settings.cmm or
;   ./work-settings.cmm for adding customer specific settings and commands, which
;   should be executed after the boot phase of the TRACE32 software.
;   This will avoid additional user actions/modifications after each TRACE32
;   software update.
; @Keywords: trace32, startup, setup, menu, toolbar, autostore, history
; @Author: -
; @Copyright: (C) 1989-2017 Lauterbach GmbH, licensed for use with TRACE32(R) only
; --------------------------------------------------------------------------------
; $Id: t32.cmm 11511 2017-10-12 15:19:18Z hlohn $


; --------------------------------------------------------------------------------
; --------------------------------------------------------------------------------

; --------------------------------------------------------------------------------
; Choose hex mode as default for input values
; --------------------------------------------------------------------------------
  RADIX Hex


; --------------------------------------------------------------------------------
; choose a different TRACE32 menu file e.g. Japanese (default: english)
; --------------------------------------------------------------------------------

  IF LANGUAGE()!=""
  (
     LOCAL  &menuname
     &menuname="~~/t32"+LANGUAGE()+".men"
     IF OS.FILE(&menuname)
        MENU.ReProgram &menuname
  )


; --------------------------------------------------------------------------------
; Integrator Probes pulldown (Logic Analyzer)
; --------------------------------------------------------------------------------

  IF Integrator()
  (
     IF (Integrator.ANALOG()>0)
     (
        IF (Integrator.ANALOG()&1)==1
        (
         ; Reset MUX setup
           I.PI_MUX_RESET

         ; Define Addresslines
           I.PI_MUX  amux.0   I.A0
           I.PI_MUX  amux.1   I.A1
           I.PI_MUX  amux.2   I.A2
           I.PI_MUX  amux.3   I.A3
           I.PI_MUX  amux.4   I.A4
           I.PI_MUX  amux.5   I.A5
           I.PI_MUX  amux.6   I.A6
           I.PI_MUX  amux.7   I.A7
           I.PI_MUX  amux.8   I.A8
           I.PI_MUX  amux.9   I.A9
           I.PI_MUX  amux.10  I.A10
           I.PI_MUX  amux.11  I.A11

         ; Programming of MUX setup
           I.PI_MUX_PROGRAM

         ; Menu-ADC-Trigger
           &file= "t32adc.men"
           &dir=  "demo/powerintegrator/probeanalog"
           IF      OS.FILE("~~/&dir/&file")
                   MENU.ReProgram "~~/&dir/&file"
           ELSE IF OS.FILE("~~/&file")
                   MENU.ReProgram "~~/&file"
           ELSE
                   DIALOG.OK "Couldn't find file '&file'."
        )
        ELSE
        (
           PRINT  "Please connect AnalogProbe to connector A for trigger support!"
        )
     )
     IF (Integrator.USB()>0)
     (
        IF (Integrator.USB()&1)==1
        (
           &file= "menprobeusb_def.men"
           &dir=  "demo/powerintegrator/probeusb2"
           IF      OS.FILE("~~/&dir/&file")
                   MENU.ReProgram "~~/&dir/&file"
           ELSE IF OS.FILE("~~/&file")
                   MENU.ReProgram "~~/&file"
           ELSE
                   DIALOG.OK "Couldn't find file '&file'."
        )
        ELSE
        (
           PRINT  "Please connect USB2 Probe to connector A/B!"
        )
     )
  )


; --------------------------------------------------------------------------------
; Recall and define TRACE32 command history file
; --------------------------------------------------------------------------------
  AutoSTOre , HISTory BookMark


; --------------------------------------------------------------------------------
; Start TRACE32 Welcome dialog               (activated since TRACE32 DVD 09/2014)
; window is only displayed if not disabled by user
; --------------------------------------------------------------------------------
  IF !(ICE()||FIRE()||ESI()||STG())&&(VERSION.BUILD()>=57090.)
     WELCOME.STARTUP


; --------------------------------------------------------------------------------
; Call special setting files from customer (similar application preferences)
; system-settings.cmm : contains general/default settings from customer for all
;                       users
; user-settings.cmm   : contains user specific settings, individual for each user
; work-settings.cmm   : contains project specific settings selected by the working
;                       directory from which TRACE32 was started
; --------------------------------------------------------------------------------

  IF OS.FILE("~~/system-settings.cmm")
     DO "~~/system-settings.cmm"

  IF VERSION.BUILD()>54763.
  (
     PRIVATE  &uad
     &uad=VERSION.ENVironment(UAD)
     IF OS.FILE("&uad/user-settings.cmm")
        DO "&uad/user-settings.cmm"
  )

  IF OS.FILE("./work-settings.cmm")
     DO "./work-settings.cmm"

; --------------------------------------------------------------------------------
; Example content for ~~/system-settings.cmm :
;
; Add some extra buttons to the toolbar
; --------------------------------------------------------------------------------

;  MENU.ReProgram
;  (
;     ADD
;     TOOLBAR
;     (
;        TOOLITEM  "Peripherals"      ":chip"     "Per.view"
;        SEPARATOR
;     )
;  )


ENDDO

; --------------------------------------------------------------------------------
; --------------------------------------------------------------------------------