; --------------------------------------------------------------------------------
; @Title: Linux Demo for TRACE32 OS Awareness
; @Description:
;
;   This batchfile demonstrates the use of the OS Awareness for Linux
;
;   The example is generated for an AMCC Ocotea 440GX board using an ICD.
;   It will NOT run on any other board, but may be used as a template
;   for others.
;
; @Keywords: awareness, linux, ocotea, RTOS
; @Author: DIE
; @Board: AMCC-Ocotea-440GX
; @Chip: PPC440GX
; @Copyright: (C) 1989-2015 Lauterbach GmbH, licensed for use with TRACE32(R) only
; --------------------------------------------------------------------------------
; $Id: linux.cmm 13987 2019-02-19 16:15:20Z kjmal $


; set CONFIG_BDI_SWITCH to prevent Linux accessing debug registers

; Starting Linux example with TRACE32:
; - Connect NULL modem cable to J11/RS232-1 (lower jack)
; - Start TRACE32
; - Switch on the board
; - TRACE32: "do linux"
; - Terminal: login as root and start "hello"

 LOCAL &ka_path &awareness &term


; Debugger Reset

 WinPAGE.RESet
 AREA.RESet
 WinPOS 0. 23. 70. 9. 0. 0. W000
 AREA.view

 PRINT "resetting..."
 RESet


; Open serial terminal window

 &term="COM3"
 SCREEN.ALways
 PRINT "starting terminal on &term"
 TERM.METHOD COM &term 115200.
 TERM.SIZE 80. 1000.
 TERM.Mode VT100
 TERM.SCROLL ON
 WinPOS 91. 0. 80. 25.
 TERM.view


; Initializing Debugger

 PRINT "initializing..."
 SYStem.CPU PPC440GX
 SYStem.Option DataTrace ON     ; enable data trace for 440 (needs patching!)
 SYStem.Option MMUSPACES ON     ; enable space ids to virtual addresses
 SYStem.Up
 Register.RESet

 SETUP.IMASKASM ON              ; lock interrupts while single stepping


; Target Setup: initialize board memory access and peripherals

 ; let the boot monitor setup the board
 Go
 PRINT "target setup..."
 WAIT 4.s
 Break

 ; Flush the caches before downloading Linux!
 CACHE.FLUSH DC
 CACHE.FLUSH IC

 ; Set SDR0_PFC0 to CPU Trace for flow trace capability
 PER.Set.SaveIndex DCR:0x0E %Long 0x4100 0x4100 DCR:0x0F %Long 0x3f00


; Load the Linux kernel

 ; If you are using a flashed kernel, or if you're loading
 ; your kernel via TFTP, use the boot monitor to do so.

 ; Use the next lines (loading linux image, setting
 ; registers and board info structure) only when
 ; loading the kernel into RAM using the debugger.

 ; vmlinux starts physically at RAM start.
 ; We have to adjust it from the virtual start address
 ; to the physical start address
 ; i.e.: Data.LOAD.Elf vmlinux <physical start>-<virtual start>

 PRINT "loading Linux kernel..."
 Data.LOAD.Elf vmlinux 0x0-0xc0000000 /gnu /NosYmbol

 Register.RESet

 ; set PC on start address of image
 Register.Set IP 0

 ; Fill in board info (bd_t structure) for linux boot
 DO board_info


; Loading initial ram disk (initrd)

 ; Use the next lines only, if you want to use an initrd,
 ; and if you want to download this with the debugger.

 ; Load ram file system image into ram disk
 ; The load address is either hardcoded in arch/arm/<board>/arch.c,
 ; or must be passed by a boot parameter, or as command line option

 PRINT "loading ramdisk..."
 Data.LOAD.Binary ramdisk.image.gz 0x0300000 /NoClear /NosYmbol

 Register.Set R4 0x0300000     ; R4 points to initrd
 Register.Set R5 0x0480000     ; R5 points to end of initrd


; Load the Linux kernel symbols into the debugger
 ; /strippart and /path are used to map source paths

 PRINT "loading Linux kernel symbols..."
 Data.LOAD.Elf vmlinux /gnu /NoCODE /StripPART 3
 sYmbol.CLEANUP.sYmbols


; Open a Code Window -- we like to see something

 WinPOS 0. 0. 75. 20.
 List.auto


; Declare the MMU format to the debugger
 ; - table format is "LINUX"
 ; - table base address is at label "swapper_pg_dir"
 ; - kernel address translation
 ; Map the virtual kernel symbols to physical addresses to give
 ; the debugger access to it before CPU MMU is initialized

 PRINT "initializing debugger MMU..."
 MMU.FORMAT LINUXEXT swapper_pg_dir 0xc0000000--0xcfffffff 0x00000000
 TRANSlation.COMMON 0xc0000000--0xffffffff              ; common area for kernel and processes
 TRANSlation.TableWalk ON   ; debugger uses a table walk to decode virtual addresses
 TRANSlation.ON             ; switch on debugger(!) address translation


; Initialize Linux Support

 ; Note that the Linux awareness needs the kernel symbols to work

 ; check linux major version
 IF STRing.SCAN(Data.STRing(linux_banner), "Linux version 2.", 0)==0
 (
     &ka_path="~~/demo/powerpc/kernel/linux/linux-2.x"
     &awareness="linux.t32"
 )
 ELSE
 (
     &ka_path="~~/demo/powerpc/kernel/linux/awareness"
     &awareness="linux.t32"
 )

 PRINT "initializing RTOS support..."
 TASK.CONFIG &ka_path/&awareness       	; loads Linux awareness
 MENU.ReProgram &ka_path/linux    	; loads Linux menu

 ; Group kernel area to be displayed with red bar
 GROUP.Create "kernel" 0xc0000000--0xffffffff /RED


; Ok, we're done, let's start Linux

 Go
 PRINT "starting Linux... (please wait)"
 WAIT 3.s
 Break

 PRINT "done."     ; done with loading and starting Linux


; --------------------------------------------------------------------------------
;       Application Debugging
;           e.g. "hello"
; --------------------------------------------------------------------------------

 ; activate autoloader for processes:
 TASK.sYmbol.Option AutoLoad Process

 PRINT "please log in and start 'hello'"

 ; script based
   ; using the script based application debugging
   ; gives more control over the single commands
   ; see file "app_debug.cmm"

   LOCAL &extdir
   &extdir=TASK.GETDIR()
   DO &extdir/app_debug hello

 ; process watch system
   ; the process watch system automates the actions
   ; for application debugging

   ;WinPOS 55. 25. 40. 4.
   ;TASK.Watch.View "hello"

   ;Go

 ENDDO