; --------------------------------------------------------------------------------
; @Title: Linux Demo for TRACE32 OS Awareness
; @Description: 
;   
;   This batchfile demonstrates the use of the OS Awareness for Linux
;   
;   The example is generated for an MPC837xMDS board using an ICD.
;   It will NOT run on any other board, but may be used as a template
;   for others.
;   
; @Keywords: awareness, linux, mpc837xmds, RTOS
; @Author: DIE
; @Board: MPC837xMDS
; @Chip: MPC8378
; @Copyright: (C) 1989-2015 Lauterbach GmbH, licensed for use with TRACE32(R) only
; --------------------------------------------------------------------------------
; $Id: linux.cmm 13987 2019-02-19 16:15:20Z kjmal $


; Starting Linux example with TRACE32 and console terminal:
; - Connect STRAIGHT modem cable to RS232-1
; - Start TRACE32
; - Open console terminal: 115200 baud, 8/N/1, no(!) handshake
; - (T32) "do linux"
; - (term) start "hello"

 LOCAL &ka_path &awareness
 LOCAL &srcdrive
 LOCAL &srcpath
 &srcdrive="S:"
 &srcpath="&srcdrive"+"\linux\linux\"


 SCREEN.ON


; Debugger Reset

 WinPAGE.RESet
 AREA.RESet
 WinPOS 0. 23. 70. 8. 0. 0. W000
 AREA.view
 
 PRINT "resetting..."

 SYStem.Down
 TASK.RESet
 Break.RESet
 MAP.RESet
 sYmbol.RESet
 TRANSlation.RESet
 

; Initializing Debugger

 PRINT "initializing..."
 SYStem.CPU MPC8378
 SYStem.BdmClock 20MHz          ; increase speed
 SYStem.Option MMUSPACES ON     ; enable space ids to virtual addresses
 
 SYStem.Up
 
 Register.RESet
 SETUP.IMASKASM ON              ; lock interrupts while single stepping
 

; Target Setup: initialize board memory access and peripherals
 PRINT "target setup..."

 ; Either let the boot monitor setup the board
    Go.direct
    WAIT 3.s
    Break.direct
 ; or use the debugger to initialize it
    ;do mpc837xmds


; Load the Linux kernel

 ; If you are using a flashed kernel, or if you're loading 
 ; your kernel via TFTP, use the boot monitor to do so.
 
 ; Use the next lines (loading linux image, setting 
 ; registers and board info structure) only when
 ; loading the kernel into RAM using the debugger.

 ; vmlinux starts physically at RAM start.
 ; We have to adjust it from the virtual start address 
 ; to the physical start address
 ; i.e.: Data.LOAD.Elf vmlinux <physical start>-<virtual start>
 
 PRINT "loading Linux kernel..."
 Data.LOAD.Elf vmlinux 0x0-0xc0000000 /NosYmbol /noreg
 
 Register.RESet

 ; set PC on start address of image
 Register.Set IP 0
 Register.Set R1 0x3FFF00   ; stack pointer for early startup routines
 

 ; Load device tree blob for Linux boot sequence

 PRINT "loading device tree..."
 Data.LOAD.Binary mpc837x_mds.dtb 0x450000 /NosYmbol
 
 Register.Set R3 0x450000   ; R3 points to device tree


; Loading initial ram disk (initrd)

 ; Use the next lines only, if you want to use an initrd,
 ; and if you want to download this with the debugger.

 ; Load ram file system image into ram disk
 ; The load address is coded into the device tree structure

 PRINT "loading ramdisk..."
 Data.LOAD.Binary ramdisk.image.gz 0x0500000 /NoClear /NosYmbol
   

; Load the Linux kernel symbols into the debugger
 ; /strippart and /path are used to map source paths
 
 PRINT "loading Linux kernel symbols..."
 ;Data.LOAD.Elf vmlinux /nocode /strippart 3 /path "S:\" 
 Data.LOAD.Elf vmlinux /NoCODE /StripPART 2 /PATH "&srcpath" 
 sYmbol.CLEANUP     ; necessary!

 
; Open a Code Window -- we like to see something

 WinPOS 0. 0. 75. 20.
 List.auto
 SCREEN.display
 

; Declare the MMU format to the debugger
 ; - table format is "LINUX"
 ; - table base address is at label "swapper_pg_dir"
 ; - kernel address translation
 ; Map the virtual kernel symbols to physical addresses to give 
 ; the debugger access to it before CPU MMU is initialized

 PRINT "initializing debugger MMU..."
 MMU.FORMAT LINUX swapper_pg_dir 0xc0000000--0xc1ffffff 0x00000000
 TRANSlation.COMMON 0xc0000000--0xffffffff              ; common area for kernel and processes
 TRANSlation.TableWalk ON   ; debugger uses a table walk to decode virtual addresses
 TRANSlation.ON             ; switch on debugger(!) address translation 
 

; Initialize Linux Support

 ; Note that the Linux awareness needs the kernel symbols to work
 
 ; check linux major version
 IF STRing.SCAN(Data.STRing(linux_banner), "Linux version 2.", 0)==0
 (
     &ka_path="~~/demo/powerpc/kernel/linux/linux-2.x"
     &awareness="linux.t32"
 )
 ELSE
 (
     &ka_path="~~/demo/powerpc/kernel/linux/linux-3.x"
     &awareness="linux3.t32"  
 )
 
 PRINT "initializing RTOS support..."
 TASK.CONFIG &ka_path/&awareness       	; loads Linux awareness 
 MENU.ReProgram &ka_path/linux    	; loads Linux menu 
  
 ; Group kernel area to be displayed with red bar
 GROUP.Create "kernel" 0xc0000000--0xffffffff /RED


; Disable power down mode
 Data.Assemble ppc6xx_idle+0xa0 nop     ; HID0


; Ok, we're done, let's start Linux

 Go.direct
 PRINT "starting Linux... (please wait)"
 WAIT 3.s
 Break.direct
 
 PRINT "done."     ; done with loading and starting Linux

 
; -------------------------------------------------------------------------------- 
;       Application Debugging 
;           e.g. "hello" 
; --------------------------------------------------------------------------------

 ; activate autoloader for processes:
 TASK.sYmbol.Option AutoLoad Process

 PRINT "please log in and start 'hello'"

 ; script based
   ; using the script based application debugging
   ; gives more control over the single commands
   ; see file "app_debug.cmm"
   
   LOCAL &extdir
   &extdir=TASK.GETDIR()
   DO &extdir/app_debug hello
   
 ; process watch system
   ; the process watch system automates the actions
   ; for application debugging
   
   ;WINPOS 55. 25. 40. 4.
   ;TASK.Watch.View "hello"

   ;Go

 ENDDO