; --------------------------------------------------------------------------------
; @Title: Linux Demo for TRACE32 OS Awareness
; @Description: 
;   
;   This batchfile demonstrates the use of the OS Awareness for Linux
;   
;   The example is generated for an MPC8360E board using an ICD.
;   It will NOT run on any other board, but may be used as a template
;   for others.
;   
; @Keywords: awareness, linux, mpc8360e, RTOS
; @Author: DIE
; @Board: MPC8360E
; @Chip: MPC8360
; @Copyright: (C) 1989-2015 Lauterbach GmbH, licensed for use with TRACE32(R) only
; --------------------------------------------------------------------------------
; $Id: linux.cmm 13987 2019-02-19 16:15:20Z kjmal $


; Starting Linux example with TRACE32 and console terminal:
; - Connect STRAIGHT modem cable to RS232-1
; - Start TRACE32
; - Open console terminal: 115200 baud, 8/N/1, no(!) handshake
; - TRACE32: "do linux"
; - terminal: login as root/root
; - terminal: start "hello"

 LOCAL &ka_path &awareness

 SCREEN.ALways      ; permanent update for internal terminal window
 ; screen.on        ; if you use external terminal


; Debugger Reset

 WinPAGE.RESet
 AREA.RESet
 WinPOS 0. 23. 70. 8. 0. 0. W000
 AREA.view
 
 PRINT "resetting..."

 SYStem.Down
 TASK.RESet
 Break.RESet
 MAP.RESet
 sYmbol.RESet
 TRANSlation.RESet
 

; Initializing Debugger

 PRINT "initializing..."
 SYStem.CPU MPC8360
 SYStem.BdmClock 20MHz          ; increase speed
 SYStem.Option NODEBUGSTOP OFF
 SYStem.Option BASE AUTO        ; get reset io base address
 SYStem.Option WATCHDOG ON
 SYStem.Option MMUSPACES ON     ; enable space ids to virtual addresses
 
 SYStem.Up
 
 Register.RESet
 SETUP.IMASKASM ON              ; lock interrupts while single stepping
 

; Open serial terminal window on COM1
 
 TERM.RESet
 TERM.METHOD COM COM1 115200. 8 NONE 1STOP NONE 
 TERM.Mode ASCII
 TERM.SIZE 80. 1000.
 TERM.SCROLL ON
 WinPOS 35. 0. ,,,,, TERM.view
 TERM.view
 

; Target Setup: initialize board memory access and peripherals
 PRINT "target setup..."

 ; Either let the boot monitor setup the board
    Go.direct
    WAIT 7.s
    Break.direct
 ; or use the debugger to initialize it
    ;do mpc837xmds


; Load the Linux kernel

 ; If you are using a flashed kernel, or if you're loading 
 ; your kernel via TFTP, use the boot monitor to do so.
 
 ; Use the next lines (loading linux image, setting 
 ; registers and board info structure) only when
 ; loading the kernel into RAM using the debugger.

 ; vmlinux starts physically at RAM start.
 ; We have to adjust it from the virtual start address 
 ; to the physical start address
 ; i.e.: Data.LOAD.Elf vmlinux <physical start>-<virtual start>
 
 PRINT "loading Linux kernel..."
 Data.LOAD.Elf vmlinux 0x0-0xc0000000 /NosYmbol /noreg
 
 Register.RESet

 ; set PC on start address of image
 Register.Set IP 0
 Register.Set R1 0x3FFF00   ; stack pointer for early startup routines
 
 ; Fill in board info (bd_t structure) for linux boot
 DO board_info


; Loading initial ram disk (initrd)

 ; Use the next lines only, if you want to use an initrd,
 ; and if you want to download this with the debugger.

 ; Load ram file system image into ram disk
 ; The load address is coded into the device tree structure

 PRINT "loading ramdisk..."
 Data.LOAD.Binary rootfs.ext2.gz 0x00500000 /NoClear /NosYmbol
   
 Register.Set R4 0x00500000     ; R4 points to initrd
 Register.Set R5 0x00900000     ; R5 points to end of initrd

; Load the Linux kernel symbols into the debugger
 ; /strippart and /path are used to map source paths
 
 PRINT "loading Linux kernel symbols..."
 Data.LOAD.Elf vmlinux /NoCODE
 sYmbol.CLEANUP     ; necessary!

 
; Open a Code Window -- we like to see something

 WinPOS 0. 0. 75. 20.
 List.auto
 SCREEN.display
 

; Declare the MMU format to the debugger
 ; - table format is "LINUX"
 ; - table base address is at label "swapper_pg_dir"
 ; - kernel address translation
 ; Map the virtual kernel symbols to physical addresses to give 
 ; the debugger access to it before CPU MMU is initialized

 PRINT "initializing debugger MMU..."
 TRANSlation.FORMAT LINUX swapper_pg_dir 0xc0000000--0xcfffffff 0x00000000
 TRANSlation.COMMON 0xc0000000--0xffffffff              ; common area for kernel and processes
 TRANSlation.TableWalk ON   ; debugger uses a table walk to decode virtual addresses
 TRANSlation.ON             ; switch on debugger(!) address translation 
 

; Initialize Linux Support

 ; Note that the Linux awareness needs the kernel symbols to work
 
 ; check linux major version
 IF STRing.SCAN(Data.STRing(linux_banner), "Linux version 2.", 0)==0
 (
     &ka_path="~~/demo/powerpc/kernel/linux/linux-2.x"
     &awareness="linux.t32"
 )
 ELSE
 (
     &ka_path="~~/demo/powerpc/kernel/linux/linux-3.x"
     &awareness="linux3.t32"  
 )
 
 PRINT "initializing RTOS support..."
 TASK.CONFIG &ka_path/&awareness       	; loads Linux awareness 
 MENU.ReProgram &ka_path/linux    	; loads Linux menu 
  
 ; Group kernel area to be displayed with red bar
 GROUP.Create "kernel" 0xc0000000--0xffffffff /RED


; Ok, we're done, let's start Linux

 wintop TERM.view        ; set terminal window to front
 Go.direct
 PRINT "starting Linux... (please wait)"
 WAIT 10.s
 Break.direct
 
 PRINT "done."     ; done with loading and starting Linux

 
; -------------------------------------------------------------------------------- 
;       Application Debugging 
;           e.g. "hello" 
; --------------------------------------------------------------------------------

 ; activate autoloader for processes:
 TASK.sYmbol.Option AutoLoad Process

 PRINT "please log in and start 'hello'"

 ; script based
   ; using the script based application debugging
   ; gives more control over the single commands
   ; see file "app_debug.cmm"
   
   LOCAL &extdir
   &extdir=TASK.GETDIR()
   DO &extdir/app_debug hello
   
 ; process watch system
   ; the process watch system automates the actions
   ; for application debugging
   
   ;WINPOS 55. 25. 40. 4.
   ;TASK.Watch.View "hello"

   ;Go

 ENDDO