; --------------------------------------------------------------------------------
; @Title: Example script for programming of MPC5553 internal flash.
;
; @Description:
; Script arguments:
;
;   DO mpc5553 [PREPAREONLY] [SKIPCONFIG] [PORTSHARING=ON|OFF]
;
;     PREPAREONLY only declares flash but does not execute flash programming
;     SKIPCONFIG  skip configuration part to allow script external configuration
;     PORTSHARING=ON|OFF enable/disable port sharing for e.g. calibtration tools
;
; Example:
;
;   DO ~~/demo/powerpc/flash/mpc5553 PREPAREONLY SKIPCONFIG
;
; Internal Flash Memory 1.5 MByte:
;   Low address range   256 kByte (16, 48, 48, 16, 64, 64 kByte)
;                       0x00000000--0x0003ffff
;   Mid address range   256 kByte (2 * 128 kByte)
;                       0x00040000--0x0007ffff
;   High address range  1.0 MByte (8 * 128 kByte)
;                       0x00080000--0x0017ffff
;   Shadow row          1 kByte
;                       0x00fffc00--0x00ffffff
; 
; Internal SRAM         64 kByte
;                       0x40000000--0x4000ffff 
;
; Flash register base address is 0xc3f88000
;
; Version of flash algorithm may depend on processor revision:
;   MPC5553 Rev 0 or higher         h7fa_v311.bin or higher
;
;   h7fa.bin contains latest version of flash algorithm.
;
; NOTES:
; 
;   Flash register base address has to be 0xc3f88000, because target
;   program does currently not support another base address.
;
;   Programming a 32 byte row more than once until next erasure may
;   cause bus error on this row. To avoid such problems FLASH.AUTO
;   can be used for programming.
;
; @Author: WRD
; @Chip: MPC5553
; @Copyright: (C) 1989-2017 Lauterbach GmbH, licensed for use with TRACE32(R) only
; --------------------------------------------------------------------------------
; $Rev: 5830 $
; $Id: mpc5553.cmm 5830 2018-07-16 15:25:52Z rweiss $
;


LOCAL &parameters &param_prepareonly &param_skipconfig &param_portsharing
ENTRY %LINE &parameters
&param_prepareonly=(STRing.SCAN(STRing.UPpeR("&parameters"),"PREPAREONLY",0)!=-1)
&param_skipconfig=(STRing.SCAN(STRing.UPpeR("&parameters"),"SKIPCONFIG",0)!=-1)
&param_portsharing=STRing.SCANAndExtract(STRing.UPpeR("&parameters"),"PORTSHARING=","")

LOCAL &flashdriver &flashsize &optimize
&flashdriver="~~/demo/powerpc/flash/quad/h7fa.bin"
&flashsize=0x000100000

; Optimize flash programming time by switching on PLL
&optimize=0

LOCAL &DualPort
IF VERSION.BUILD.BASE()>=45520.
  &DualPort="/DualPort"

; --------------------------------------------------------------------------------
; CPU setup

IF !&param_skipconfig
(
  SYStem.RESet
  IF "&param_portsharing"!=""
    SYStem.CONFIG PortSHaring &param_portsharing
  SYStem.BdmClock 4.0MHz
  SYStem.CPU MPC5553
  SYStem.Up

  IF &optimize==1
  (
    ; setup PLL
    Data.Set ASD:0xC3F80000 %Long 0x06000000
    ; set JTAG clock to 25 MHz
    SYStem.BdmClock 25MHz
  )
)

; Initialize internal SRAM
Data.Set EA:0x40000000--0x4000FFFF %Quad 0

; Setup MMU for flash, RAM and register access
MMU.Set TLB1 0x0 0x00000000 0x00000000 0x00000000
MMU.Set TLB1 0x1 0xC0000500 0xFFF0000A 0xFFF0003F
MMU.Set TLB1 0x2 0xC0000700 0x20000000 0x2000003F
MMU.Set TLB1 0x3 0xC0000400 0x40000008 0x4000003F
MMU.Set TLB1 0x4 0xC0000500 0xC3F00008 0xC3F0003F
MMU.Set TLB1 0x5 0xC0000700 0x00000000 0x0000003F

; set BIUAPR register to make Flash memory visible for Nexus
Data.Set ASD:0xC3F88020 %Long 0x000000FF

; --------------------------------------------------------------------------------
; Flash declaration

FLASH.RESet

FLASH.Create 1. 0x00000000++0x03fff TARGET Quad 0. ; L0
FLASH.Create 1. 0x00004000++0x0bfff TARGET Quad 1. ; L1 
FLASH.Create 1. 0x00010000++0x0bfff TARGET Quad 2. ; L2 
FLASH.Create 1. 0x0001c000++0x03fff TARGET Quad 3. ; L3
FLASH.Create 1. 0x00020000++0x0ffff TARGET Quad 4. ; L4
FLASH.Create 1. 0x00030000++0x0ffff TARGET Quad 5. ; L5
FLASH.Create 2. 0x00040000++0x1ffff TARGET Quad 0. ; M0
FLASH.Create 2. 0x00060000++0x1ffff TARGET Quad 1. ; M1

LOCAL &flashaddr &Hx
&flashaddr=0x00080000
&Hx=0.
WHILE &flashaddr<0x000180000
(
  FLASH.Create 3. &flashaddr++0x1ffff TARGET Quad &Hx ; H0..H7
  &flashaddr=&flashaddr+0x20000
  &Hx=&Hx+1.
)
; Shadow row
FLASH.Create 4. 0x00fffc00++0x3ff NOP Quad /CENSORSHIP 0x00FFFDD8--0x00FFFDE7

FLASH.TARGET E:0x40000000 E:0x40002000 0x1000 &flashdriver &DualPort

;flash script ends here if called with parameter PREPAREONLY
IF &param_prepareonly
  ENDDO

; --------------------------------------------------------------------------------
; Flash programming example
;
; Flash programming speed is about three times faster when memory class E:
; is used for data buffer (DUALPORT memory access). For DUALPORT access it
; is required to setup MemAccess NEXUS for both, NEXUS and JTAG debugger. 

DIALOG.YESNO "Flash programming prepared. Program flash memory now?"
LOCAL &progflash
ENTRY &progflash

IF &progflash 
(
  FLASH.ReProgram ALL /Erase
  Data.LOAD.auto *
  FLASH.ReProgram.off 
)
ELSE
(
  FLASH.List
)

;set JTAG clock back to default
SYStem.BdmClock 4MHz

ENDDO