; --------------------------------------------------------------------------------
; @Title: Example script for programming of MPC5534 internal flash.
;
; @Description:
; Script arguments:
;
;   DO mpc5534 [PREPAREONLY] [SKIPCONFIG]
;
;     PREPAREONLY only declares flash but does not execute flash programming
;     SKIPCONFIG  skip configuration part to allow script external configuration
;
; Example:
;
;   DO ~~/demo/powerpc/flash/mpc5534 PREPAREONLY SKIPCONFIG
;
; Internal Flash Memory 1.0 MByte:
;   Low address range   256 kByte (16, 48, 48, 16, 64, 64 kByte)
;                       0x00000000--0x0003ffff
;   Mid address range   256 kByte (2 * 128 kByte)
;                       0x00040000--0x0007ffff
;   High address range  512 kByte (4 * 128 kByte)
;                       0x00080000--0x000fffff
;   Shadow row          32 kByte
;                       0x00ff8000--0x00ffffff
; 
; Internal SRAM         48 kByte
;                       0x40000000--0x4000bfff 
;
; Flash register base address is 0xc3f88000
;
; Flash algorithm may depend on processor revision:
;   MPC5534 Rev 0                 h7fb_v301.bin 
;   MPC5534 higher revisions      h7fb_v320.bin or higher
;
;   h7fb.bin contains latest version of flash algorithm.
;
; NOTES:
; 
;   Flash register base address has to be 0xc3f88000, because target
;   program does currently not support another base address.
;
; @Author: rweiss
; @Chip: MPC5534
; @Copyright: (C) 1989-2017 Lauterbach GmbH, licensed for use with TRACE32(R) only
; --------------------------------------------------------------------------------
; $Rev: 5830 $
; $Id: mpc5534.cmm 5830 2018-07-16 15:25:52Z rweiss $
;


LOCAL &parameters &param_prepareonly &param_skipconfig
ENTRY %LINE &parameters
&param_prepareonly=(STRing.SCAN(STRing.UPpeR("&parameters"),"PREPAREONLY",0)!=-1)
&param_skipconfig=(STRing.SCAN(STRing.UPpeR("&parameters"),"SKIPCONFIG",0)!=-1)

LOCAL &flashdriver &flashsize &optimize
&flashdriver="tbd.bin"
&flashsize=0x000100000

; Optimize flash programming time by switching on PLL
&optimize=0

LOCAL &DualPort
IF VERSION.BUILD.BASE()>=45520.
  &DualPort="/DualPort"

; --------------------------------------------------------------------------------
; CPU setup

IF !&param_skipconfig
(
  SYStem.RESet
  SYStem.BdmClock 4.0MHz
  SYStem.CPU MPC5534
  SYStem.Up

  IF &optimize==1
  (
    ; setup PLL
    Data.Set ASD:0xC3F80000 %Long 0x06000000
    ; set JTAG clock to 25 MHz
    SYStem.BdmClock 25MHz
  )
)

; initialize internal SRAM
Data.Set EA:0x40000000--0x4000bfff %Quad 0

; setup MMU for flash, RAM and register access
MMU.Set TLB1 0x0 0x00000000 0x00000000 0x00000000
MMU.Set TLB1 0x1 0xC0000500 0xFFF0000A 0xFFF0003F
MMU.Set TLB1 0x2 0xC0000700 0x20000000 0x2000003F
MMU.Set TLB1 0x3 0xC0000400 0x40000008 0x4000003F
MMU.Set TLB1 0x4 0xC0000500 0xC3F00008 0xC3F0003F
MMU.Set TLB1 0x5 0xC0000700 0x00000000 0x0000003F

; set BIUAPR register to make Flash memory visible for Nexus
Data.Set ASD:0xC3F88020 %Long 0x000000FF

; --------------------------------------------------------------------------------
; Check SIU_MIDR register to select flash driver depending on processor 
; revision
LOCAL &corerevision
&corerevision=Data.Long(EA:0xC3F90004)
PRINT "Core revision 0x" &corerevision
IF &corerevision==0x55340000
(
  PRINT %ERROR "FLASH programming not supported for processor revision 0"
  END
)
ELSE 
(
  ; Other core revisions
  &flashdriver="~~/demo/powerpc/flash/quad/h7fb.bin"
)

; --------------------------------------------------------------------------------
; Flash declaration

FLASH.RESet

FLASH.Create 1. 0x00000000++0x03fff TARGET Quad 0. ; L0
FLASH.Create 1. 0x00004000++0x0bfff TARGET Quad 1. ; L1 
FLASH.Create 1. 0x00010000++0x0bfff TARGET Quad 2. ; L2 
FLASH.Create 1. 0x0001c000++0x03fff TARGET Quad 3. ; L3
FLASH.Create 1. 0x00020000++0x0ffff TARGET Quad 4. ; L4
FLASH.Create 1. 0x00030000++0x0ffff TARGET Quad 5. ; L5
FLASH.Create 2. 0x00040000++0x1ffff TARGET Quad 0. ; M0
FLASH.Create 2. 0x00060000++0x1ffff TARGET Quad 1. ; M1

LOCAL &flashaddr &Hx
&flashaddr=0x00080000
&Hx=0.
WHILE &flashaddr<0x000100000
(
  FLASH.Create 3. &flashaddr++0x1ffff TARGET Quad &Hx ; H0..H3
  &flashaddr=&flashaddr+0x20000
  &Hx=&Hx+1.
)
; Shadow row
FLASH.Create 4. 0x00ff8000++0x7fff NOP Quad /CENSORSHIP 0x00FFFDD8--0x00FFFDE7

FLASH.TARGET E:0x40000000 E:0x40002000 0x1000 &flashdriver &DualPort

;flash script ends here if called with parameter PREPAREONLY
IF &param_prepareonly
  ENDDO

; --------------------------------------------------------------------------------
; Flash programming example
;
; Flash programming speed is about three times faster when memory class E:
; is used for data buffer (DUALPORT memory access). For DUALPORT access it
; is required to setup MemAccess NEXUS for both, NEXUS and JTAG debugger. 

DIALOG.YESNO "Flash programming prepared. Program flash memory now?"
LOCAL &progflash
ENTRY &progflash

IF &progflash 
(
  FLASH.ReProgram ALL /Erase
  Data.LOAD.auto *
  FLASH.ReProgram.off 
)
ELSE
(
  FLASH.List
)

;set JTAG clock back to default
SYStem.BdmClock 4MHz

ENDDO