; --------------------------------------------------------------------------------
; @Title: Example script for programming of MPC564xA/SPC564Axx internal flash.
;
; @Description:
; MPC5644A/SPC564A80: Internal Flash Memory 4 MByte
; MPC5642A/SPC564A70: Internal Flash Memory 2 MByte
;
; NOTES:
; 
;   Flash register base addresses cannot be remapped, because target
;   program does currently not support another base address.
;
; @Author: rweiss
; @Chip: MPC564?A SPC564A*
; @Copyright: (C) 1989-2017 Lauterbach GmbH, licensed for use with TRACE32(R) only
; --------------------------------------------------------------------------------
; $Rev: 5830 $
; $Id: jpc564xa.cmm 5830 2018-07-16 15:25:52Z rweiss $
;

; Check if script is called with parameters
; Valid parameters:
;   PREPAREONLY     : prepare flash programming without user interaction
;   SKIPCONFIG      : skip configuration part to allow script external configuration
LOCAL &parameters &param_prepareonly &param_skipconfig
ENTRY %LINE &parameters
&param_prepareonly=(STRing.SCAN(STRing.UPpeR("&parameters"),"PREPAREONLY",0)!=-1)
&param_skipconfig=(STRing.SCAN(STRing.UPpeR("&parameters"),"SKIPCONFIG",0)!=-1)

LOCAL &flashsize &flasharrays &flashdriver
&flashsize="tbd"
&flasharrays="tbd"
&flashdriver="tbd.bin"

LOCAL &DualPort
IF VERSION.BUILD.BASE()>=45520.
  &DualPort="/DualPort"

; --------------------------------------------------------------------------------
; CPU setup

IF !&param_skipconfig
(
  SYStem.RESet
  SYStem.BdmClock 4.0MHz
  SYStem.CPU MPC55XX
  SYStem.DETECT.CPU
  SYStem.Option.WATCHDOG OFF
  SYStem.Up
)

;check processor revision
LOCAL &NPC_DID
&NPC_DID=Data.Long(DBG:0x80)
IF (&NPC_DID&0x0FFFFF00)==0x0AE02000 // 4M silicon
  &flasharrays=2
ELSE
  &flasharrays=1

IF (CPU()=="MPC5642A")||(CPU()=="SPC564A70")
  &flashsize=0x000200000
ELSE
  &flashsize=0x000400000

IF &flasharrays==1
  &flashdriver="~~/demo/powerpc/flash/quad/c90fl564xl.bin"
ELSE  
  &flashdriver="~~/demo/powerpc/flash/quad/c90fl5674.bin"

; initialize internal SRAM
Data.Set EA:0x40000000--0x40007fff %Quad 0

; setup MMU for flash, RAM and register access
MMU.Set TLB1 0x0 0x00000000 0x00000000 0x00000000
MMU.Set TLB1 0x1 0xC0000500 0xFFF0000A 0xFFF0003F
MMU.Set TLB1 0x2 0xC0000700 0x20000000 0x2000003F
MMU.Set TLB1 0x3 0xC0000400 0x40000008 0x4000003F
MMU.Set TLB1 0x4 0xC0000500 0xC3F00008 0xC3F0003F
MMU.Set TLB1 0x5 0xC0000700 0x00000000 0x0000003F

; --------------------------------------------------------------------------------
; Flash declaration

FLASH.RESet

; LAS
FLASH.Create 1. 0x00000000++0x03fff TARGET Quad 0.  ; L0 bank 0
FLASH.Create 1. 0x00004000++0x03fff TARGET Quad 1.  ; L1 bank 0
FLASH.Create 1. 0x00008000++0x03fff TARGET Quad 2.  ; L2 bank 0
FLASH.Create 1. 0x0000c000++0x03fff TARGET Quad 3.  ; L3 bank 0
FLASH.Create 1. 0x00010000++0x03fff TARGET Quad 4.  ; L4 bank 0
FLASH.Create 1. 0x00014000++0x03fff TARGET Quad 5.  ; L5 bank 0
FLASH.Create 1. 0x00018000++0x03fff TARGET Quad 6.  ; L6 bank 0
FLASH.Create 1. 0x0001c000++0x03fff TARGET Quad 7.  ; L7 bank 0
FLASH.Create 1. 0x00020000++0x0ffff TARGET Quad 8.  ; L8 bank 0
FLASH.Create 1. 0x00030000++0x0ffff TARGET Quad 9.  ; L9 bank 0

IF (&flasharrays==1)
(
  ; MAS
  FLASH.Create 2. 0x00040000++0x1ffff TARGET Quad 0. ; M0 bank 0
  FLASH.Create 2. 0x00060000++0x1ffff TARGET Quad 1. ; M1 bank 0

  ; HAS
  LOCAL &Hx &flashaddr
  &Hx=0.
  &flashaddr=0x00080000
  WHILE &flashaddr<&flashsize
  (
    FLASH.Create 3. &flashaddr++0x3ffff TARGET Quad &Hx ; H0..H5 bank 0 + bank 1
    &flashaddr=&flashaddr+0x40000
    &Hx=&Hx+1.
  )
  
  ; Shadow row
  FLASH.Create 4. 0x00ffc000++0x3fff NOP Quad /CENSORSHIP 0x00fffdd8--0x00fffde7 /INFO "Shadow Row"
)
ELSE
(
  ; LAS
  FLASH.Create 1. 0x00040000++0x1ffff TARGET Quad 10. ; M0 bank 0
  FLASH.Create 1. 0x00060000++0x1ffff TARGET Quad 11. ; M1 bank 0

  ; MAS
  FLASH.Create 2. 0x00080000++0x3ffff TARGET Quad 0.  ; L0 bank 1
  FLASH.Create 2. 0x000c0000++0x3ffff TARGET Quad 1.  ; M0 bank 1

  ; HAS
  LOCAL &Hx &flashaddr
  &Hx=0.
  &flashaddr=0x00100000
  WHILE &flashaddr<&flashsize
  (
    FLASH.Create 3. &flashaddr++0x7ffff TARGET Quad &Hx ; H0..H5 bank 0 + bank 1
    &flashaddr=&flashaddr+0x80000
    &Hx=&Hx+1.
  )
  
  ; Shadow rows
  FLASH.Create 4. 0x00ffc000++0x3fff NOP Quad /CENSORSHIP 0x00fffdd8--0x00fffde7 /INFO "Shadow Row B"
  FLASH.Create 5. 0x00efc000++0x3fff NOP Quad /INFO "Shadow Row A"
)

FLASH.TARGET E:0x40000000 E:0x40004000 0x1000 &flashdriver /STACKSIZE 0x0200 &DualPort

;flash script ends here if called with parameter PREPAREONLY
IF &param_prepareonly
  ENDDO

; --------------------------------------------------------------------------------
; Flash programming example
;
; Flash programming speed is about three times faster when memory class E:
; is used for data buffer (DUALPORT memory access). For DUALPORT access it
; is required to setup MemAccess NEXUS for both, NEXUS and JTAG debugger. 

DIALOG.YESNO "Flash programming prepared. Program flash memory now?"
LOCAL &progflash
ENTRY &progflash

IF &progflash 
(
  FLASH.ReProgram ALL /Erase
  Data.LOAD.auto *
  FLASH.ReProgram.off 
)
ELSE
(
  FLASH.List
)

ENDDO