; --------------------------------------------------------------------------------
; @Title: Generic script for Fujitsu MB9B360R series internal flash
;
; @Description:
;
; Example for flash declaration and programming of Fujitsu MB9B360R series
; internal flash.
;
; Script arguments:
;
;   DO mb9b360r [CPU=<cpu>] [PREPAREONLY]
;
;     CPU=<cpu> selects CPU derivative <cpu>
;
;     PREPAREONLY only declares flash but does not execute flash programming
;
; Example:
;
;   DO ~~/demo/arm/flash/mb9b360r CPU=MB9BF368R PREPAREONLY
;
; List of MB9B360R series derivatives and their configuration:
;
;   CPU-Type       Main Flash   Work Flash   RAM
;                     [kB]         [kB]      [kB]
; --------------------------------------------------------------------------------
;   MB9BF366M         512.          32.       64.
;   MB9BF366N         512.          32.       64.
;   MB9BF366R         512.          32.       64.
;   MB9BF367M         768.          32.       96.
;   MB9BF367N         768.          32.       96.
;   MB9BF367R         768.          32.       96.
;   MB9BF368M        1024.          32.      128.
;   MB9BF368N        1024.          32.      128.
;   MB9BF368R        1024.          32.      128.
;
; @Chip: MB9BF36?M MB9BF36?N MB9BF36?R
; @Author: WRD
; @Copyright: (C) 1989-2019 Lauterbach GmbH, licensed for use with TRACE32(R) only
; --------------------------------------------------------------------------------
; $Rev: 7602 $
; $Id: mb9b360r.cmm 7602 2019-11-05 15:02:25Z bschroefel $
;

  LOCAL &parameters
  ENTRY %LINE &parameters

  LOCAL &param_cpu &param_prepareonly
  &param_prepareonly=(STRing.SCAN(STRing.UPpeR("&parameters"),"PREPAREONLY",0)!=-1)
  &param_cpu=STRing.SCANAndExtract(STRing.UPpeR("&parameters"),"CPU=","")

  ; ------------------------------------------------------------------------------
  ; Start debugging

  IF SYStem.MODE()<5
  (
    Break.RESet
    SYStem.RESet

    IF "&param_cpu"!=""
      SYStem.CPU &param_cpu
    IF !CPUIS(MB9BF36*)
      SYStem.CPU MB9BF36*

    IF CABLE.TWOWIRE()
      SYStem.CONFIG.DEBUGPORTTYPE SWD
    ELSE
      SYStem.CONFIG.DEBUGPORTTYPE JTAG

    SYStem.Option.ResBreak OFF
    SYStem.Up
  )

  ; ------------------------------------------------------------------------------
  ; Flash declaration

  FLASH.RESet
  GOSUB FlashDeclaration

  ; Flash script ends here if called with parameter PREPAREONLY
  IF &param_prepareonly
    ENDDO PREPAREDONE

  ; ------------------------------------------------------------------------------
  ; Flash programming example

  DIALOG.YESNO "Program flash memory?"
  LOCAL &progflash
  ENTRY &progflash
  IF &progflash 
  (
    FLASH.ReProgram.ALL /Erase
    Data.LOAD.auto *
    FLASH.ReProgram.off

    ; Reset device
    SYStem.Down
    SYStem.Up
  )

  ENDDO


; --------------------------------------------------------------------------------
; Flash declaration depending on selected CPU 

FlashDeclaration:
  LOCAL &FlashSize

  IF CPUIS("MB9BF366?")
    &FlashSize=0x80000
  ELSE IF CPUIS("MB9BF367?")
    &FlashSize=0xC0000
  ELSE IF CPUIS("MB9BF368?")
    &FlashSize=0x100000
  ELSE
  (
    PRINT %ERROR "FLASH size of CPU type is unknown"
    ENDDO
  )

  ; Program flash
  IF &FlashSize>=0x80000
  (
    FLASH.Create 1. 0x000000--0x007FFF  0x2000 TARGET Long
    FLASH.Create 1. 0x008000--0x00FFFF  0x8000 TARGET Long
    FLASH.Create 1. 0x010000--0x07FFFF 0x10000 TARGET Long
  )
  IF &FlashSize>=0xC0000
  (
    FLASH.Create 1. 0x080000--0x0BFFFF 0x10000 TARGET Long
  )
  IF &FlashSize>=0x100000
  (
    FLASH.Create 1. 0x0C0000--0x0FFFFF 0x10000 TARGET Long
  )

  ; Work flash
  FLASH.Create 2. 0x200C0000--0x200C7FFF 0x2000 TARGET Word

  FLASH.TARGET 0x1FFFF000 0x20000000 0x1000 ~~/demo/arm/flash/word/fm4.bin

  RETURN