; --------------------------------------------------------------------------------
; @Title: Example for flash declaration of Fujitsu MB9A130N series internal flash.
;
; @Description: 
; Script arguments:
;
;   DO mb9a130n [PREPAREONLY] [CPU=<cpu>]
;
;     PREPAREONLY only declares flash but does not execute flash programming
;
;     CPU=<cpu> selects CPU derivative <cpu>
;
; Example:
;
;   DO ~~/demo/arm/flash/mb9a130n CPU=MB9AF132N PREPAREONLY
;
; List of MB9A130N series derivatives and their configuration:
;
;   CPU-Type   FlashSize   RamSize
;                 [kB]       [kB]
;   ------------------------------
;   MB9AF131M      64.       12.
;   MB9AF131N      64.       12.
;   MB9AF132M     128.       16.
;   MB9AF132N     128.       16.
;
; @Author: WRD
; @Copyright: (C) 1989-2019 Lauterbach GmbH, licensed for use with TRACE32(R) only
; @Chip: MB9AF13?N* MB9AF13?M*
; --------------------------------------------------------------------------------
; $Rev: 7602 $
; $Id: mb9a130n.cmm 7602 2019-11-05 15:02:25Z bschroefel $

  LOCAL &parameters &param_prepareonly
  ENTRY %LINE &parameters
  &param_prepareonly=(STRing.SCAN(STRing.UPpeR("&parameters"),"PREPAREONLY",0)!=-1)

  LOCAL &param_cpu
  &param_cpu=STRing.SCANAndExtract(STRing.UPpeR("&parameters"),"CPU=","")

  ; --------------------------------------------------------------------------------
  ; Start debugging

  IF SYStem.MODE()<5
  (
    Break.RESet
    SYStem.RESet

    IF "&param_cpu"!=""
      SYStem.CPU &param_cpu
    IF !CPUIS(MB9AF13?N*)&&!CPUIS(MB9AF13?M*)
      SYStem.CPU MB9AF13*

    IF CABLE.TWOWIRE()
      SYStem.CONFIG.DEBUGPORTTYPE SWD
    ELSE
      SYStem.CONFIG.DEBUGPORTTYPE JTAG

    SYStem.Option.ResBreak OFF
    SYStem.Up
  )

  ; --------------------------------------------------------------------------------
  ; Flash declaration

  FLASH.RESet
  GOSUB FlashDeclaration

  ; --------------------------------------------------------------------------------
  ; Flash programming example

  ; Flash script ends here if called with parameter PREPAREONLY
  IF &param_prepareonly
    ENDDO PREPAREDONE

  DIALOG.YESNO "Program flash memory?"
  LOCAL &progflash
  ENTRY &progflash
  IF &progflash 
  (
    FLASH.ReProgram.ALL /Erase
    Data.LOAD.auto *
    FLASH.ReProgram.off

    ; Reset device
    SYStem.Down
    SYStem.Up
  )

  ENDDO


; --------------------------------------------------------------------------------
; Flash declaration depending on selected CPU 

FlashDeclaration:
  LOCAL &FlashSize

  IF CPUIS("MB9AF131N*")||CPUIS("MB9AF131M*")
  (
    &FlashSize=0x10000
  )
  ELSE IF CPUIS("MB9AF132N*")||CPUIS("MB9AF132M*")
  (
    &FlashSize=0x20000
  )
  ELSE
  (
    PRINT %ERROR "FLASH size of CPU type is unknown"
    ENDDO
  )

  IF &FlashSize>=0x10000
  (
    FLASH.Create 1. 0x000000--0x000FFF  0x1000 TARGET Word
    FLASH.Create 1. 0x001000--0x00FFFF  0xF000 TARGET Word
  )
  IF &FlashSize>=0x20000
  (
    FLASH.Create 1. 0x010000--0x01FFFF 0x10000 TARGET Word
  )

  FLASH.TARGET 0x20000000 0x20000800 0x1000 ~~/demo/arm/flash/word/fm3t3.bin

  RETURN