; ---------------------------------------------------------------------------
; load_symbols.cmm
; ---------------------------------------------------------------------------
  PMACRO.EXPLICIT

  LOCAL &file_flashsetup
  PRIVATE &result &count_hex &count_elfm &count_elfs &count_orti

  ; show path and name of this script (present practice file)
  ECHO ""
  ECHO %COLOR.BLUE "### " OS.PPF() " ###"

; ---------------------------------------------------------------------------

  ; get active flashsetup file
  GOSUB File_Read "&file_user_flash"
  RETURNVALUES &file_flashsetup

  ECHO %COLOR.GREEN "Processing FlashSetup file: &file_flashsetup"

  IF FILE.EXIST("&file_flashsetup")
  (
    DO "flash_checkfiles.cmm" "&file_flashsetup"
    RETURNVALUES &result &count_hex &count_elfm &count_elfs &count_orti

    IF &result
    (
      IF ((&count_elfm==0)&&(&count_elfs==0))
      (
        DIALOG.OK "ERROR: FlashSetup file contains no valid file specification!"+CONVert.CHAR(0x0D0A)+"&file_flashsetup"
      )
      ELSE
      (
        IF (&count_elfm>0)
        (
          DO "flash_loadelf.cmm" "&file_flashsetup" "&dir_base" "[ELF-M]"
        )
        IF (&count_elfs>0)
        (
          InterCom M4 DO "flash_loadelf.cmm" "&file_flashsetup" "&dir_base" "[ELF-S]"
        )
        IF (&count_orti>0)
        (
          InterCom M4 DO "flash_loadorti.cmm" "&file_flashsetup" "&dir_base" "[ORTI]"
        )
      )
    )
  )

  ENDDO



; ---------------------------------------------------------------------------
File_Read:
  PARAMETERS &fread
  PRIVATE &inputline

  &inputline=""
  IF FILE.EXIST("&fread")
  (
    OPEN #1 "&fread" /Read
    READ #1 %LINE &inputline
    CLOSE #1
  )
  RETURN "&inputline"